The following code inserts a user zoom level into the zoomInfo stack of BLT:

proc AddZoomStack { } {
  global g zoomInfo
  set cmd {}
  foreach margin { xaxis yaxis x2axis y2axis } {
    foreach axis [$g $margin use] {
      set min [$g axis cget $axis -min]; set max [$g axis cget $axis -max]
      set c [list $g axis configure $axis -min $min -max $max]
      append cmd "$c\n"
      }
    }
  set zoomInfo($g,stack) [linsert $zoomInfo($g,stack) 0 $cmd]
  }

 
   can't read "zoomInfo(.r.gr.c,stack)": no such variable

Without having tested it myself would you like to try this snippet instead?

proc AddZoomStack {g} {
  set cmd {}
  foreach margin { xaxis yaxis x2axis y2axis } {
    foreach axis [$g $margin use] {
      set min [$g axis cget $axis -min]
      set max [$g axis cget $axis -max]
      set c [list $g axis configure $axis -min $min -max $max]
      append cmd "$c\n"
    }
  }
  set ::blt::zoomInfo($g,stack) [linsert $::blt::zoomInfo($g,stack) 0 $cmd]
}

Thank you, that solves this!

Which is very strange because earlier in the script I

   namespace import ::blt::*

With the explicit ::blt::zoomInfo, it finds the stack under both.

Thanks again, we can close this ticket!

Wait, spoke too soon.

Now it runs under undroidwish/vanillawish, but does NOT find it under the native wish 8.6, BLT 2.5.3. (it did work under native wish 8.5, BLT 2.4z)

The error message now is

   cant't read "::blt::zoomInfo(...,stack)": no such variable

So we need to refine the proc like so (again untested):

proc AddZoomStack {g} {
  set cmd {}
  foreach margin { xaxis yaxis x2axis y2axis } {
    foreach axis [$g $margin use] {
      set min [$g axis cget $axis -min]
      set max [$g axis cget $axis -max]
      set c [list $g axis configure $axis -min $min -max $max]
      append cmd "$c\n"
    }
  }
  if {[info exists ::blt::zoomInfo]} {
    set ::blt::zoomInfo($g,stack) [linsert $::blt::zoomInfo($g,stack) 0 $cmd]
  } elseif {[info global zoomInfo] eq "zoomInfo"} {
    set ::zoomInfo($g,stack) [linsert $::zoomInfo($g,stack) 0 $cmd]
  }
}